Initial commit

2022-01-08 19:46:18 +01:00
commit 57ba5a5858
207 changed files with 12402 additions and 0 deletions
--- a/build.gradle.kts
+++ b/build.gradle.kts
@ -0,0 +1,128 @@
+import ProjectVersions.openosrsVersion
+
+buildscript {
+    repositories {
+        gradlePluginPortal()
+    }
+}
+
+plugins {
+    java
+    checkstyle
+}
+
+project.extra["GithubUrl"] = "https://github.com/yuri-moens/chaos-plugins"
+
+apply<BootstrapPlugin>()
+
+allprojects {
+    group = "io.reisub"
+    apply<MavenPublishPlugin>()
+}
+
+allprojects {
+    apply<MavenPublishPlugin>()
+
+    repositories {
+        mavenLocal()
+    }
+}
+
+subprojects {
+    group = "io.reisub.openosrs"
+
+    project.extra["PluginProvider"] = "ChaosEnergy"
+    project.extra["ProjectSupportUrl"] = "https://github.com/yuri-moens/chaos-plugins/issues"
+    project.extra["PluginLicense"] = "3-Clause BSD License"
+
+    repositories {
+        mavenCentral {
+            content {
+                excludeGroupByRegex("com\\.openosrs.*")
+            }
+        }
+
+        jcenter {
+            content {
+                excludeGroupByRegex("com\\.openosrs.*")
+            }
+        }
+
+        exclusiveContent {
+            forRepository {
+                mavenLocal()
+            }
+            filter {
+                includeGroupByRegex("com\\.openosrs.*")
+            }
+        }
+    }
+
+    apply<JavaPlugin>()
+
+    dependencies {
+        annotationProcessor(Libraries.lombok)
+        annotationProcessor(Libraries.pf4j)
+
+        compileOnly("com.openosrs:http-api:$openosrsVersion+")
+        compileOnly("com.openosrs:runelite-api:$openosrsVersion+")
+        compileOnly("com.openosrs:runelite-client:$openosrsVersion+")
+        compileOnly("com.openosrs.rs:runescape-api:$openosrsVersion+")
+        compileOnly("com.openosrs.externals:iutils:4+")
+
+        compileOnly(Libraries.findbugs)
+        compileOnly(Libraries.apacheCommonsText)
+        compileOnly(Libraries.gson)
+        compileOnly(Libraries.guice)
+        compileOnly(Libraries.javax)
+        compileOnly(Libraries.lombok)
+        compileOnly(Libraries.okhttp3)
+        compileOnly(Libraries.pf4j)
+        compileOnly(Libraries.rxjava)
+    }
+
+    configure<JavaPluginConvention> {
+        sourceCompatibility = JavaVersion.VERSION_11
+        targetCompatibility = JavaVersion.VERSION_11
+    }
+
+    configure<PublishingExtension> {
+        repositories {
+            maven {
+                url = uri("$buildDir/repo")
+            }
+        }
+        publications {
+            register("mavenJava", MavenPublication::class) {
+                from(components["java"])
+            }
+        }
+    }
+
+    tasks {
+        withType<JavaCompile> {
+            options.encoding = "UTF-8"
+        }
+
+        withType<Jar> {
+            doLast {
+                copy {
+                    from("./build/libs/")
+                    into("../release/")
+                }
+            }
+        }
+
+        withType<AbstractArchiveTask> {
+            isPreserveFileTimestamps = false
+            isReproducibleFileOrder = true
+            dirMode = 493
+            fileMode = 420
+        }
+
+        register<Copy>("copyDeps") {
+            into("./build/deps/")
+            from(configurations["runtimeClasspath"])
+        }
+    }
+}